Screenshot Active Window

[Dorian (MJT support)]

I've recently made some changes to this, so I've deleted the old thread and am re-posting.

In my role as customer support, I often need to send screenshots of one particular window.

This script will :

• Detect the active window.
  Calculate the size and location of the window.
  Screenshot only that one window.
  Save the screenshot as Screenshot-YYYY-MM-DD-HH-MM-SS.bmp
  Open the screenshot in folder (optional) for easy dragging and dropping.
  Open the screenshot in Paint (optional) for easy editing.

Just make sure to assign it a hotkey.

I use it daily, and I hope it helps you as much as it's helped me.

//Note. Make sure to assign this macro a Hot Key.

//Show the screenshot in Windows Explorer? yes/no
Let>ShowInFolder=yes

//Edit the screenshot in MS Paint? yes/no
Let>EditFile=no

//Get the active window
GetActiveWindow>ActiveWin,Xpos,Ypos,Width,Height

//Calculate the window size
Let>BottomRightX=Xpos+Width
Let>BottomRightY=Ypos+Height

//Get time and date for the filename
Year>TheYear
Month>TheMonth
Day>TheDay
Hour>TheHour
Min>TheMin
Sec>TheSec

//Set file path and name
Let>FilePath=%USERDOCUMENTS_DIR%\Screenshots
Let>FileName=%FilePath%\Screenshot-%TheYear%-%TheMonth%-%TheDay%-%TheHour%-%TheMin%-%TheSec%.bmp

//Create the output folder if it doesn't exist
IfNotDirExists>%FilePath%
CreateDir>%FilePath%
Endif

//Capture the screenshot
ScreenCapture>Xpos,Ypos,%BottomRightX%,%BottomRightY%,%FileName%

//Show the screenshot in Windows Explorer if ShowInFolder = yes
if>ShowInFolder=yes
RunProgram>Explorer /select,%FileName%
Endif


//Edit the screenshot in MS Paint if EditFile = yes
If>EditFile=yes
RunProgram>msPaint.exe %FileName%
WaitWindowOpen>Paint*
WaitReady>1
WindowAction>1,Paint*
Endif
  View Snippet Page

[HSEIVANE]

Is it possible to send every screenshot by gmail?
and add the macro name to the screenshot?

[Dorian (MJT support)]

Yes. SMTPSendMail, and send the image as an attachment.

I think you'll find it useful looking at the System Variables at the bottom of the Command Reference. Reading that is a goldmine of information and may just open up a whole new world for you. Script_Name is probably the one you want, but I'd encourage you to look at the list as there are others there which may help you.

[HSEIVANE]

I just tried Script_Name but it doesn't insert it in the file name.

[Dorian (MJT support)]

How about %script_name% ?

[nodochau]

Dorian,
Thank you a lot for your share.

[Dorian (MJT support)]

Dorian,
Thank you a lot for your share.

Always a pleasure.